Googleスプレッドシートでガントチャート作成：開始・終了日付を変えるだけで自動更新

Googleスプレッドシートを開き、メニューの「挿入」から「表」をクリックします。

その後、画面右に表示される表の中から「プロジェクトのタスク」を選択します。

表のうち、以下の列を入力します。

• A列：タスク名（任意）
• D列：ステータス
• E列：開始日
• F列：終了日

その他の列は不要であれば、数式入力後に削除しても問題ありません。

K1セルに以下の数式を入力します。

アレイフォーミュラ関数を使用しているため、K1以降の列は自動で日付が表示されます。

日付を自動入力する数式

=IF(COUNTA(E2:E)=0, "", ARRAYFORMULA(MIN(FILTER(E2:E, E2:E<>"")) + SEQUENCE(1, MAX(FILTER(F2:F, F2:F<>"")) - MIN(FILTER(E2:E, E2:E<>"")) + 1, 0)))

E列の中で最も早い開始日からF列の最も遅い終了日までの日付が自動で横に展開されます。

この数式を使うことで、ガントチャートの土台となる横軸を作成できます。

K2セルに以下の数式を入力します。

こちらの数式もアレイフォーミュラ関数を使用しているため、K2以降のセルも自動で数式が適用されます。

タスク期間を横軸に表示する数式

=ARRAYFORMULA(IF((($E2:$E<>"") * ($F2:$F<>"")) * (K$1:1 >= $E2:$E) * (K$1:1 <= $F2:$F), $D2:$D, ""))

この数式では、該当する期間のセルにステータスが表示されるだけなので、条件付き書式で色付けしてガントチャートにします。

スプレッドシートのメニュー「表示形式」から「条件付き書式」をクリックします。

色分けする範囲

ガントチャートの全体範囲を適用します。

例： K2:CA15

条件付き書式のルール設定

カスタム数式を選択し、それぞれのタスクを色分けします。

1. 開始前の場合
   • 数式：=k2="開始前"
   • テキストの色：青
   • 塗りつぶし：青
2. 処理中の場合
   • 数式：=k2="処理中"
   • テキストの色：黄色
   • 塗りつぶし：黄色
3. ブロック済みの場合
   • 数式：=k2="ブロック済み"
   • テキストの色：赤
   • 塗りつぶし：赤
4. 完了の場合
   • 数式：=k2="完了"
   • テキストの色：緑
   • 塗りつぶし：緑

テキストの色と、塗りつぶしを同じ色にすることで文字が見えなくなり、チャートだけが表示されます。

E列の開始日、F列の終了日を変更すると、チャートも変更されます。